Microsoft激推しのCopilotキーでChatGPTを開いてしまおう

2024年12月24日

30年ぶりにPCに新しいキーが追加されたとのことで話題になったCopilot in Windowsですが、私も３年ぶりにPCを新調し（今回は富士通の非常に軽量なFMV Zeroにしました）、ついにCopilotキーを手に入れました。しかし、実際にCopilotアプリを日常的に使うかというと…だいぶ微妙ですよね。まだOSに実用的なレベルでAIが統合されていない中で、将来への準備と話題を集めるためにキーを追加したような気がしています。実際、現在のCopilotよりもChatGPTのサービスの方が、最新のLLMを選べたりCode Interpreterなどの新機能が使えて便利だと思います（ChatGPT Plusにも課金しているなら尚更）。という訳で、Microsoftには申し訳ないですが新しいPCを買った後の最初の作業として、さっさとCopilotキーをChatGPTアプリにリマップしてしまいましょう！（もちろん、この記事を参考にすればChatGPTだけでなく他のアプリを開くように設定することも可能です）

※尚、ChatGPTの標準機能としてAlt + spaceを押すとCompanion Chatが起動するので既に近いことはできるのですが、過去のチャット一覧を見ることができず、ちょっと使い勝手が悪いです。

Step 1: ChatGPTのApp IDを取得

まず、Windows用のChatGPTをMicrosoft Storeからインストールしておいてください。 Microsoft Storeからインストールしたアプリをスクリプトで起動するためには、そのアプリのApp IDを知っておく必要があります。このIDはおそらくアプリがバージョンアップしても不変なはずですが、場合によっては変わってしまうこともあり得るので、その場合はあとで説明するスクリプトを、新しいIDに書き換えてください。

ChatGPTアプリをインストールしたら、PowerShellを立ち上げ、Get-StartAppsと打つと、現在のユーザーがインストールしているアプリとそのIDの一覧が出てくるので、ChatGPTのIDをコピーしておいてください。OpenAI.ChatGPT-Desktop_********!ChatGPTみたいな形式のはずです。

以降、２種類の方法を解説しますが、最初のAutoHotKeyを用いた方がChatGPTが起動するまでのラグが少なかったのでおすすめです。

Step 2: AutoHotKeyで実装

まずはAutoHotKeyをインストールしてください。これはWindows上でいろいろなタスクを自動化できるオープンソースのスクリプト言語です。

answers.microsoft.comのLyleSchemmerlingさんの回答によると、Copilotキーを押すとWindows + Shift + F23というショートカットが実行されているそうです。なので、このショートカットが押されたときに

ChatGPTがすでに起動している場合、ウィンドウを前面に持ってくる
そうでない場合、起動する

という処理をすれば大丈夫です。ついでに、ChatGPTと別のアプリの行き来をしやすくするために

すでにChatGPTウィンドウが前面にある場合、キーが押されたら前のアプリに戻る（とりあえず、Alt + Tabをエミュレートすることで実装可能）

という機能もつけてしまいましょう。Copilotキーを押す度にアプリとチャットを切り替えられるので、結構便利だと思います。（単純な実装なので、マルチモニタ環境だとAlt + Tabだと「現在のモニタで最後に使われていたアプリ」が起動してしまい意図しない挙動になるかもしれません…）

以下のスクリプトをlaunch_chatgpt.ahkのようなファイル名で保存してください。CHATGPT_APP_IDの部分は先ほど取得したApp IDに変更してください。

#Requires AutoHotkey v2.0+
; Place this script in the 'shell:startup' folder so it runs automatically on every boot.

; Hotkey: Left Win + Left Shift + F23 (corresponds to the Copilot key)
<+<#F23::
{
    ; Define the executable name of the ChatGPT app
    appExe := "ChatGPT.exe"

    ; Check if the ChatGPT app is currently active
    if WinActive("ahk_exe " . appExe) {
        ; Emulate Alt+Tab to return to the previous application
        Send("{Alt Down}{Tab}")
        Sleep(100)  ; Small delay to ensure smooth execution
        Send("{Alt Up}")
    } else {
        ; Check if the ChatGPT app is running
        if WinExist("ahk_exe " . appExe) {
            ; If running, bring ChatGPT to the foreground
            WinActivate("ahk_exe " . appExe)
        } else {
            ; If not running, launch the ChatGPT app
            Run("shell:AppsFolder\CHATGPT_APP_ID")
        }
    }
    return
}

保存したら、試しにファイルをダブルクリックしてこのスクリプトを読み込んでから、Copilotキーを押してChatGPTが起動するか試してみてください。・

Win + Rを押してshell:startupと入力するとスタートアッププログラムのフォルダが開きます。ここにこの.ahkファイルを保存すれば、起動するたびに実行されてこのショートカットが有効化されます。

Step 2 (別方法): PowerToysで実装（おすすめしません）

尚、Windowsの（準）標準機能のPowerToysでこれを実現する方法もあるのですが、.batファイル経由でアプリを起動しようとすると１秒ほど時間がかかってしまうので使い勝手が悪く、採用しませんでした。参考程度にその方法も一応短く書いておきます。

ChatGPTアプリを起動する.batファイルを作成(AppIDについては前述)
- start shell:AppsFolder\CHATGPT_APP_ID
その.batファイルを起動するショートカットを作成
- .batファイルを右クリック→「その他のオプションを確認」で出てきます。
- なぜショートカットを挟むかというと、次のステップのShortcut keyの割り当てが.batファイル自体にはできなかったためです。
そのショートカットファイルのプロパティを開いて「ショートカット」タブ内で、Ctrl + Alt + Aなど適当なショートカットを割り当てる
PowerToysのKeyboard Managerの「ショートカットの再マップ」で、Windows + Shift + F23を先ほどのCtrl + Alt + Aに割り当てる